Index: rtol/cmake/modules/FindR.cmake
===================================================================
--- rtol/cmake/modules/FindR.cmake	(revision cdd8fcaab303102a39a4a6853673dbf36b3d309b)
+++ rtol/cmake/modules/FindR.cmake	(revision cdd8fcaab303102a39a4a6853673dbf36b3d309b)
@@ -0,0 +1,117 @@
+
+#
+# - This module locates an installed R distribution.
+#
+# Defines the following:
+#  R_COMMAND           - Path to R command
+#  Rscript_COMMAND     - Path to Rscript command
+#  R_HOME              - Path to 'R home', as reported by R
+#  R_INCLUDE_DIR       - Path to R include directory
+#  R_LIBRARY_BASE      - Path to R library
+#  R_LIBRARY_BLAS      - Path to Rblas / blas library
+#  R_LIBRARY_LAPACK    - Path to Rlapack / lapack library
+#  R_LIBRARY_READLINE  - Path to readline library
+#  R_LIBRARIES         - Array of: R_LIBRARY_BASE, R_LIBRARY_BLAS, R_LIBRARY_LAPACK, R_LIBRARY_BASE [, R_LIBRARY_READLINE]
+#
+#  VTK_R_HOME          - (deprecated, use R_HOME instead) Path to 'R home', as reported by R
+#
+# Variable search order:
+#   1. Attempt to locate and set R_COMMAND
+#     - If unsuccessful, generate error and prompt user to manually set R_COMMAND
+#   2. Use R_COMMAND to set R_HOME
+#   3. Locate other libraries in the priority:
+#     1. Within a user-built instance of R at R_HOME
+#     2. Within an installed instance of R
+#     3. Within external system libraries
+#
+
+set(TEMP_CMAKE_FIND_APPBUNDLE ${CMAKE_FIND_APPBUNDLE})
+set(CMAKE_FIND_APPBUNDLE "NEVER")
+find_program(R_COMMAND R DOC "R executable.")
+find_program(Rscript_COMMAND Rscript DOC "Rscript executable.")
+set(CMAKE_FIND_APPBUNDLE ${TEMP_CMAKE_FIND_APPBUNDLE})
+
+if(R_COMMAND)
+  execute_process(WORKING_DIRECTORY .
+                  COMMAND ${R_COMMAND} RHOME
+                  OUTPUT_VARIABLE R_ROOT_DIR
+                  OUTPUT_STRIP_TRAILING_WHITESPACE)
+  # deprecated
+  if(VTK_R_HOME)
+    set(R_HOME ${VTK_R_HOME} CACHE PATH "R home directory obtained from R RHOME")
+  else(VTK_R_HOME)
+    set(R_HOME ${R_ROOT_DIR} CACHE PATH "R home directory obtained from R RHOME")
+    set(VTK_R_HOME ${R_HOME})
+  endif(VTK_R_HOME)
+  # /deprecated
+  # the following command does nothing currently, but will be used when deprecated code is removed
+  set(R_HOME ${R_ROOT_DIR} CACHE PATH "R home directory obtained from R RHOME")
+
+  if( WIN32 )
+    find_path( R_INCLUDE_DIR R.h
+      PATHS ${R_ROOT_DIR}
+      PATH_SUFFIXES include R/include
+      DOC "Path to file R.h"
+      NO_DEFAULT_PATH )
+
+    if( CMAKE_SIZEOF_VOID_P EQUAL 4 )
+      set( path_suffix "i386" )
+    else( CMAKE_SIZEOF_VOID_P EQUAL 4 )
+      set( path_suffix "x64" )
+    endif( CMAKE_SIZEOF_VOID_P EQUAL 4 )
+
+    find_library(R_LIBRARY_BASE R
+      PATHS ${R_ROOT_DIR}/bin
+      PATH_SUFFIXES ${path_suffix}
+      DOC "R library (example libR.a, libR.dylib, etc.)."
+      NO_DEFAULT_PATH )
+
+    find_library(R_LIBRARY_BLAS NAMES Rblas blas
+      PATHS ${R_ROOT_DIR}/bin
+      PATH_SUFFIXES ${path_suffix}
+      DOC "Rblas library (example libRblas.a, libRblas.dylib, etc.)."
+      NO_DEFAULT_PATH )
+
+    find_library(R_LIBRARY_LAPACK NAMES Rlapack lapack
+      PATHS ${R_ROOT_DIR}/bin
+      PATH_SUFFIXES ${path_suffix}
+      DOC "Rlapack library (example libRlapack.a, libRlapack.dylib, etc.)."
+      NO_DEFAULT_PATH )
+  else( WIN32 )
+    execute_process( COMMAND ${R_COMMAND} CMD config --cppflags
+      OUTPUT_VARIABLE R_CPPFLAGS OUTPUT_STRIP_TRAILING_WHITESPACE)
+    if ( ${R_CPPFLAGS} MATCHES "[-][I]([^ ;])+" )
+      string( SUBSTRING ${CMAKE_MATCH_0} 2 -1 _INCL )
+      set( R_INCL_DIR ${_INCL} )
+      message( STATUS "R_INCL_DIR = ${RCPP_INCL_DIR}" )
+    endif( )
+
+    find_path( R_INCLUDE_DIR R.h
+      PATHS ${R_INCL_DIR}
+      DOC "Path to file R.h" )
+
+    find_library(R_LIBRARY_BASE R
+      HINTS ${R_ROOT_DIR}/lib
+      DOC "R library (example libR.a, libR.dylib, etc.).")
+
+    find_library(R_LIBRARY_BLAS NAMES Rblas blas
+      HINTS ${R_ROOT_DIR}/lib
+      DOC "Rblas library (example libRblas.a, libRblas.dylib, etc.).")
+
+    find_library(R_LIBRARY_LAPACK NAMES Rlapack lapack
+      HINTS ${R_ROOT_DIR}/lib
+      DOC "Rlapack library (example libRlapack.a, libRlapack.dylib, etc.).")
+  endif( WIN32 )
+
+  find_library(R_LIBRARY_READLINE readline
+    DOC "(Optional) system readline library. Only required if the R libraries were built with readline support.")
+
+else(R_COMMAND)
+  message(SEND_ERROR "FindR.cmake requires the following variables to be set: R_COMMAND")
+endif(R_COMMAND)
+
+# Note: R_LIBRARY_BASE is added to R_LIBRARIES twice; this may be due to circular linking dependencies; needs further investigation
+set(R_LIBRARIES ${R_LIBRARY_BASE} ${R_LIBRARY_BLAS} ${R_LIBRARY_LAPACK} ${R_LIBRARY_BASE})
+if(R_LIBRARY_READLINE)
+  set(R_LIBRARIES ${R_LIBRARIES} ${R_LIBRARY_READLINE})
+endif(R_LIBRARY_READLINE)
Index: rtol/cmake/modules/FindRINSIDE.cmake
===================================================================
--- rtol/cmake/modules/FindRINSIDE.cmake	(revision cdd8fcaab303102a39a4a6853673dbf36b3d309b)
+++ rtol/cmake/modules/FindRINSIDE.cmake	(revision cdd8fcaab303102a39a4a6853673dbf36b3d309b)
@@ -0,0 +1,55 @@
+include( LibFindMacros )
+
+find_package( R REQUIRED )
+message( STATUS "R_INCLUDE_DIR = ${R_INCLUDE_DIR}" )
+
+set( RINSIDE_FOUND 0 )
+execute_process(COMMAND ${Rscript_COMMAND} -e "Rcpp:::CxxFlags()"
+  OUTPUT_VARIABLE RCPP_FLAGS OUTPUT_STRIP_TRAILING_WHITESPACE)
+if ( ${RCPP_FLAGS} MATCHES "[-][I]([^ ;])+" )
+  string( SUBSTRING ${CMAKE_MATCH_0} 2 -1 _INCL )
+  set( RCPP_INCLUDE_DIR ${_INCL} )
+  message( STATUS "RCPP_INCLUDE_DIR = ${RCPP_INCLUDE_DIR}" )
+endif( )
+
+execute_process(COMMAND ${Rscript_COMMAND} -e "RInside:::CxxFlags()"
+  OUTPUT_VARIABLE RINSIDE_CPPFLAGS OUTPUT_STRIP_TRAILING_WHITESPACE)
+message( STATUS "RINSIDE_CPPFLAGS = ${RINSIDE_CPPFLAGS}" )
+if ( ${RINSIDE_CPPFLAGS} MATCHES "[-][I](.+)( -|$)" )
+  string( SUBSTRING ${CMAKE_MATCH_0} 2 -1 _INCL )
+  set( RINSIDE_INCLUDE_DIR ${_INCL} )
+  message( STATUS "RINSIDE_INCLUDE_DIR = ${RINSIDE_INCLUDE_DIR}" )
+endif( )
+
+execute_process( COMMAND ${Rscript_COMMAND} -e "RInside:::LdFlags()"
+  OUTPUT_VARIABLE RINSIDE_LDFLAGS OUTPUT_STRIP_TRAILING_WHITESPACE )
+if ( WIN32 )
+  set( re "^\"(.+)\"$" )
+  string( REGEX MATCH ${re} matched ${RINSIDE_LDFLAGS} )
+  if( matched )
+    set( RINSIDE_LIBRARY ${CMAKE_MATCH_1} )
+  else( matched )
+    set( RINSIDE_LIBRARY ${RINSIDE_LDFLAGS} )
+  endif( matched )
+  message( STATUS "RINSIDE_LIBRARY = ${RINSIDE_LIBRARY}" )
+  get_filename_component( RINSIDE_LIBRARY_PATH ${RINSIDE_LIBRARY} PATH )
+  message( STATUS "RINSIDE_LIBRARY_PATH = ${RINSIDE_LIBRARY_PATH}" )
+else( WIN32 )
+  if ( ${RINSIDE_LDFLAGS} MATCHES "[-][L]([^ ;])+" )
+    string( SUBSTRING ${CMAKE_MATCH_0} 2 -1 _INCL )
+    set( RINSIDE_LIBRARY_DIR ${_INCL} )
+    message( STATUS "RINSIDE_LIBRARY_DIR = ${RINSIDE_LIBRARY_DIR}" )
+    find_library( RINSIDE_LIBRARY RInside 
+      PATHS ${RINSIDE_LIBRARY_DIR}
+      NO_DEFAULT_PATH )
+    message( STATUS "RINSIDE_LIBRARY = ${RINSIDE_LIBRARY}" )
+  endif( )
+endif( WIN32 )
+
+set( RINSIDE_PROCESS_INCLUDES 
+  RCPP_INCLUDE_DIR RINSIDE_INCLUDE_DIR R_INCLUDE_DIR )
+set( RINSIDE_PROCESS_LIBS RINSIDE_LIBRARY R_LIBRARY_BASE )
+libfind_process( RINSIDE )
+
+message( STATUS "RINSIDE_INCLUDE_DIRS = ${RINSIDE_INCLUDE_DIRS}" )
+message( STATUS "RINSIDE_LIBRARIES = ${RINSIDE_LIBRARIES}" )
Index: rtol/cmake/modules/FindTOL.cmake
===================================================================
--- rtol/cmake/modules/FindTOL.cmake	(revision cdd8fcaab303102a39a4a6853673dbf36b3d309b)
+++ rtol/cmake/modules/FindTOL.cmake	(revision cdd8fcaab303102a39a4a6853673dbf36b3d309b)
@@ -0,0 +1,58 @@
+# This module defines
+# TOL_FOUND.  If false, you cannot build anything that requires TOL.
+# TOL_INCLUDE_DIR where to find the tol's header files
+# TOL_LIBRARIES, the libraries to link against to use TOL
+# also defined, but not for general use is
+# TOL_LIBRARY, the path to tol library.
+#
+# You can provide in TOL_PREFIX_PATH the path to the prefix
+# instalation of TOL.
+#
+
+include( LibFindMacros )
+
+set( TOL_FOUND 0 )
+
+if( DEFINED TOL_PREFIX_PATH )
+  if( NOT IS_ABSOLUTE ${TOL_PREFIX_PATH} )
+    file( TO_CMAKE_PATH "${CMAKE_CURRENT_BINARY_DIR}/${TOL_PREFIX_PATH}" TOL_PREFIX_PATH )
+    get_filename_component( TOL_PREFIX_PATH ${TOL_PREFIX_PATH} ABSOLUTE )
+  endif()
+  #find includes
+  find_path(
+    TOL_INCLUDE_DIR
+    NAMES "tol/tol_bcommon.h"
+    PATHS ${TOL_PREFIX_PATH}
+    PATH_SUFFIXES "include"
+    NO_DEFAULT_PATH )
+  find_library( TOL_LIBRARY
+    NAMES tol
+    PATHS ${TOL_PREFIX_PATH}
+    PATH_SUFFIXES "lib"
+    NO_DEFAULT_PATH )
+else( DEFINED TOL_PREFIX_PATH )
+
+  #find includes
+  find_path(
+    TOL_INCLUDE_DIR
+    NAMES "tol/tol_bcommon.h" )
+  find_library( TOL_LIBRARY
+    NAMES tol )
+endif( DEFINED TOL_PREFIX_PATH )
+
+set( TOL_PROCESS_INCLUDES TOL_INCLUDE_DIR )
+set( TOL_PROCESS_LIBS TOL_LIBRARY )
+libfind_process( TOL )
+
+if( TOL_FOUND )
+  add_definitions(
+    -DHAVE_CONFIG_H -DUSE_DELAY_INIT -D__USE_ZIP_ARCHIVE__
+    -D__USE_DYNSCOPE__
+    -D__POOL_NONE__=0 -D__POOL_BFSMEM__=1 -D__USE_POOL__=__POOL_BFSMEM__
+    -D__HASH_MAP_MSVC__=1 -D__HASH_MAP_GOOGLE__=2 -D__HASH_MAP_GCC__=3 
+    -D__HASH_MAP_ICC__=4 -D__USE_HASH_MAP__=__HASH_MAP_GOOGLE__ )
+  if( UNIX )
+    add_definitions( -DUNIX )
+  endif( )
+endif( TOL_FOUND )
+
Index: rtol/cmake/modules/LibFindMacros.cmake
===================================================================
--- rtol/cmake/modules/LibFindMacros.cmake	(revision cdd8fcaab303102a39a4a6853673dbf36b3d309b)
+++ rtol/cmake/modules/LibFindMacros.cmake	(revision cdd8fcaab303102a39a4a6853673dbf36b3d309b)
@@ -0,0 +1,265 @@
+# Version 2.2
+# Public Domain, originally written by Lasse KÀrkkÀinen <tronic>
+# Maintained at https://github.com/Tronic/cmake-modules
+# Please send your improvements as pull requests on Github.
+
+# Find another package and make it a dependency of the current package.
+# This also automatically forwards the "REQUIRED" argument.
+# Usage: libfind_package(<prefix> <another package> [extra args to find_package])
+macro (libfind_package PREFIX PKG)
+  set(${PREFIX}_args ${PKG} ${ARGN})
+  if (${PREFIX}_FIND_REQUIRED)
+    set(${PREFIX}_args ${${PREFIX}_args} REQUIRED)
+  endif()
+  find_package(${${PREFIX}_args})
+  set(${PREFIX}_DEPENDENCIES ${${PREFIX}_DEPENDENCIES};${PKG})
+  unset(${PREFIX}_args)
+endmacro()
+
+# A simple wrapper to make pkg-config searches a bit easier.
+# Works the same as CMake's internal pkg_check_modules but is always quiet.
+macro (libfind_pkg_check_modules)
+  find_package(PkgConfig QUIET)
+  if (PKG_CONFIG_FOUND)
+    pkg_check_modules(${ARGN} QUIET)
+  endif()
+endmacro()
+
+# Avoid useless copy&pasta by doing what most simple libraries do anyway:
+# pkg-config, find headers, find library.
+# Usage: libfind_pkg_detect(<prefix> <pkg-config args> FIND_PATH <name> [other args] FIND_LIBRARY <name> [other args])
+# E.g. libfind_pkg_detect(SDL2 sdl2 FIND_PATH SDL.h PATH_SUFFIXES SDL2 FIND_LIBRARY SDL2)
+function (libfind_pkg_detect PREFIX)
+  # Parse arguments
+  set(argname pkgargs)
+  foreach (i ${ARGN})
+    if ("${i}" STREQUAL "FIND_PATH")
+      set(argname pathargs)
+    elseif ("${i}" STREQUAL "FIND_LIBRARY")
+      set(argname libraryargs)
+    else()
+      set(${argname} ${${argname}} ${i})
+    endif()
+  endforeach()
+  if (NOT pkgargs)
+    message(FATAL_ERROR "libfind_pkg_detect requires at least a pkg_config package name to be passed.")
+  endif()
+  # Find library
+  libfind_pkg_check_modules(${PREFIX}_PKGCONF ${pkgargs})
+  if (pathargs)
+    find_path(${PREFIX}_INCLUDE_DIR NAMES ${pathargs} HINTS ${${PREFIX}_PKGCONF_INCLUDE_DIRS})
+  endif()
+  if (libraryargs)
+    find_library(${PREFIX}_LIBRARY NAMES ${libraryargs} HINTS ${${PREFIX}_PKGCONF_LIBRARY_DIRS})
+  endif()
+endfunction()
+
+# Extracts a version #define from a version.h file, output stored to <PREFIX>_VERSION.
+# Usage: libfind_version_header(Foobar foobar/version.h FOOBAR_VERSION_STR)
+# Fourth argument "QUIET" may be used for silently testing different define names.
+# This function does nothing if the version variable is already defined.
+function (libfind_version_header PREFIX VERSION_H DEFINE_NAME)
+  # Skip processing if we already have a version or if the include dir was not found
+  if (${PREFIX}_VERSION OR NOT ${PREFIX}_INCLUDE_DIR)
+    return()
+  endif()
+  set(quiet ${${PREFIX}_FIND_QUIETLY})
+  # Process optional arguments
+  foreach(arg ${ARGN})
+    if (arg STREQUAL "QUIET")
+      set(quiet TRUE)
+    else()
+      message(AUTHOR_WARNING "Unknown argument ${arg} to libfind_version_header ignored.")
+    endif()
+  endforeach()
+  # Read the header and parse for version number
+  set(filename "${${PREFIX}_INCLUDE_DIR}/${VERSION_H}")
+  if (NOT EXISTS ${filename})
+    if (NOT quiet)
+      message(AUTHOR_WARNING "Unable to find ${${PREFIX}_INCLUDE_DIR}/${VERSION_H}")
+    endif()
+    return()
+  endif()
+  file(READ "${filename}" header)
+  string(REGEX REPLACE ".*#[ \t]*define[ \t]*${DEFINE_NAME}[ \t]*\"([^\n]*)\".*" "\\1" match "${header}")
+  # No regex match?
+  if (match STREQUAL header)
+    if (NOT quiet)
+      message(AUTHOR_WARNING "Unable to find \#define ${DEFINE_NAME} \"<version>\" from ${${PREFIX}_INCLUDE_DIR}/${VERSION_H}")
+    endif()
+    return()
+  endif()
+  # Export the version string
+  set(${PREFIX}_VERSION "${match}" PARENT_SCOPE)
+endfunction()
+
+# Do the final processing once the paths have been detected.
+# If include dirs are needed, ${PREFIX}_PROCESS_INCLUDES should be set to contain
+# all the variables, each of which contain one include directory.
+# Ditto for ${PREFIX}_PROCESS_LIBS and library files.
+# Will set ${PREFIX}_FOUND, ${PREFIX}_INCLUDE_DIRS and ${PREFIX}_LIBRARIES.
+# Also handles errors in case library detection was required, etc.
+function (libfind_process PREFIX)
+  # Skip processing if already processed during this configuration run
+  if (${PREFIX}_FOUND)
+    return()
+  endif()
+
+  set(found TRUE)  # Start with the assumption that the package was found
+
+  # Did we find any files? Did we miss includes? These are for formatting better error messages.
+  set(some_files FALSE)
+  set(missing_headers FALSE)
+
+  # Shorthands for some variables that we need often
+  set(quiet ${${PREFIX}_FIND_QUIETLY})
+  set(required ${${PREFIX}_FIND_REQUIRED})
+  set(exactver ${${PREFIX}_FIND_VERSION_EXACT})
+  set(findver "${${PREFIX}_FIND_VERSION}")
+  set(version "${${PREFIX}_VERSION}")
+
+  # Lists of config option names (all, includes, libs)
+  unset(configopts)
+  set(includeopts ${${PREFIX}_PROCESS_INCLUDES})
+  set(libraryopts ${${PREFIX}_PROCESS_LIBS})
+
+  # Process deps to add to 
+  foreach (i ${PREFIX} ${${PREFIX}_DEPENDENCIES})
+    if (DEFINED ${i}_INCLUDE_OPTS OR DEFINED ${i}_LIBRARY_OPTS)
+      # The package seems to export option lists that we can use, woohoo!
+      list(APPEND includeopts ${${i}_INCLUDE_OPTS})
+      list(APPEND libraryopts ${${i}_LIBRARY_OPTS})
+    else()
+      # If plural forms don't exist or they equal singular forms
+      if ((NOT DEFINED ${i}_INCLUDE_DIRS AND NOT DEFINED ${i}_LIBRARIES) OR
+          ({i}_INCLUDE_DIR STREQUAL ${i}_INCLUDE_DIRS AND ${i}_LIBRARY STREQUAL ${i}_LIBRARIES))
+        # Singular forms can be used
+        if (DEFINED ${i}_INCLUDE_DIR)
+          list(APPEND includeopts ${i}_INCLUDE_DIR)
+        endif()
+        if (DEFINED ${i}_LIBRARY)
+          list(APPEND libraryopts ${i}_LIBRARY)
+        endif()
+      else()
+        # Oh no, we don't know the option names
+        message(FATAL_ERROR "We couldn't determine config variable names for ${i} includes and libs. Aieeh!")
+      endif()
+    endif()
+  endforeach()
+  
+  if (includeopts)
+    list(REMOVE_DUPLICATES includeopts)
+  endif()
+  
+  if (libraryopts)
+    list(REMOVE_DUPLICATES libraryopts)
+  endif()
+
+  string(REGEX REPLACE ".*[ ;]([^ ;]*(_INCLUDE_DIRS|_LIBRARIES))" "\\1" tmp "${includeopts} ${libraryopts}")
+  if (NOT tmp STREQUAL "${includeopts} ${libraryopts}")
+    message(AUTHOR_WARNING "Plural form ${tmp} found in config options of ${PREFIX}. This works as before but is now deprecated. Please only use singular forms INCLUDE_DIR and LIBRARY, and update your find scripts for LibFindMacros > 2.0 automatic dependency system (most often you can simply remove the PROCESS variables entirely).")
+  endif()
+
+  # Include/library names separated by spaces (notice: not CMake lists)
+  unset(includes)
+  unset(libs)
+
+  # Process all includes and set found false if any are missing
+  foreach (i ${includeopts})
+    list(APPEND configopts ${i})
+    if (NOT "${${i}}" STREQUAL "${i}-NOTFOUND")
+      list(APPEND includes "${${i}}")
+    else()
+      set(found FALSE)
+      set(missing_headers TRUE)
+    endif()
+  endforeach()
+
+  # Process all libraries and set found false if any are missing
+  foreach (i ${libraryopts})
+    list(APPEND configopts ${i})
+    if (NOT "${${i}}" STREQUAL "${i}-NOTFOUND")
+      list(APPEND libs "${${i}}")
+    else()
+      set (found FALSE)
+    endif()
+  endforeach()
+
+  # Version checks
+  if (found AND findver)
+    if (NOT version)
+      message(WARNING "The find module for ${PREFIX} does not provide version information, so we'll just assume that it is OK. Please fix the module or remove package version requirements to get rid of this warning.")
+    elseif (version VERSION_LESS findver OR (exactver AND NOT version VERSION_EQUAL findver))
+      set(found FALSE)
+      set(version_unsuitable TRUE)
+    endif()
+  endif()
+
+  # If all-OK, hide all config options, export variables, print status and exit
+  if (found)
+    foreach (i ${configopts})
+      mark_as_advanced(${i})
+    endforeach()
+    if (NOT quiet)
+      message(STATUS "Found ${PREFIX} ${${PREFIX}_VERSION}")
+      if (LIBFIND_DEBUG)
+        message(STATUS "  ${PREFIX}_DEPENDENCIES=${${PREFIX}_DEPENDENCIES}")
+        message(STATUS "  ${PREFIX}_INCLUDE_OPTS=${includeopts}")
+        message(STATUS "  ${PREFIX}_INCLUDE_DIRS=${includes}")
+        message(STATUS "  ${PREFIX}_LIBRARY_OPTS=${libraryopts}")
+        message(STATUS "  ${PREFIX}_LIBRARIES=${libs}")
+      endif()
+      set (${PREFIX}_INCLUDE_OPTS ${includeopts} PARENT_SCOPE)
+      set (${PREFIX}_LIBRARY_OPTS ${libraryopts} PARENT_SCOPE)
+      set (${PREFIX}_INCLUDE_DIRS ${includes} PARENT_SCOPE)
+      set (${PREFIX}_LIBRARIES ${libs} PARENT_SCOPE)
+      set (${PREFIX}_FOUND TRUE PARENT_SCOPE)
+    endif()
+    return()    
+  endif()
+
+  # Format messages for debug info and the type of error
+  set(vars "Relevant CMake configuration variables:\n")
+  foreach (i ${configopts})
+    mark_as_advanced(CLEAR ${i})
+    set(val ${${i}})
+    if ("${val}" STREQUAL "${i}-NOTFOUND")
+      set (val "<not found>")
+    elseif (val AND NOT EXISTS ${val})
+      set (val "${val}  (does not exist)")
+    else()
+      set(some_files TRUE)
+    endif()
+    set(vars "${vars}  ${i}=${val}\n")
+  endforeach()
+  set(vars "${vars}You may use CMake GUI, cmake -D or ccmake to modify the values. Delete CMakeCache.txt to discard all values and force full re-detection if necessary.\n")
+  if (version_unsuitable)
+    set(msg "${PREFIX} ${${PREFIX}_VERSION} was found but")
+    if (exactver)
+      set(msg "${msg} only version ${findver} is acceptable.")
+    else()
+      set(msg "${msg} version ${findver} is the minimum requirement.")
+    endif()
+  else()
+    if (missing_headers)
+      set(msg "We could not find development headers for ${PREFIX}. Do you have the necessary dev package installed?")
+    elseif (some_files)
+      set(msg "We only found some files of ${PREFIX}, not all of them. Perhaps your installation is incomplete or maybe we just didn't look in the right place?")
+      if(findver)
+        set(msg "${msg} This could also be caused by incompatible version (if it helps, at least ${PREFIX} ${findver} should work).")
+      endif()
+    else()
+      set(msg "We were unable to find package ${PREFIX}.")
+    endif()
+  endif()
+
+  # Fatal error out if REQUIRED
+  if (required)
+    set(msg "REQUIRED PACKAGE NOT FOUND\n${msg} This package is REQUIRED and you need to install it or adjust CMake configuration in order to continue building ${CMAKE_PROJECT_NAME}.")
+    message(FATAL_ERROR "${msg}\n${vars}")
+  endif()
+  # Otherwise just print a nasty warning
+  if (NOT quiet)
+    message(WARNING "WARNING: MISSING PACKAGE\n${msg} This package is NOT REQUIRED and you may ignore this warning but by doing so you may miss some functionality of ${CMAKE_PROJECT_NAME}. \n${vars}")
+  endif()
+endfunction()
Index: rtol/cmake/modules/MSysMacros.cmake
===================================================================
--- rtol/cmake/modules/MSysMacros.cmake	(revision cdd8fcaab303102a39a4a6853673dbf36b3d309b)
+++ rtol/cmake/modules/MSysMacros.cmake	(revision cdd8fcaab303102a39a4a6853673dbf36b3d309b)
@@ -0,0 +1,12 @@
+if( MSYS )
+  get_filename_component( msys_usr $ENV{WD} DIRECTORY )
+  set( MSYS_USR_PATH ${msys_usr} CACHE INTERNAL "" )
+endif( MSYS )
+
+macro( msys_convert_path var path )
+  if( MSYS )
+    string( REGEX REPLACE ^/usr ${MSYS_USR_PATH} ${var} ${path} )
+  else( MSYS )
+    set( ${var} ${path} PARENT_SCOPE )
+  endif( MSYS )
+endmacro( )