Ticket #899: MissingEstimation.tol

Real PutRandomSeed(2143);

//////////////////////////////////////////////////////////////////////////////
// Creación de los datos

Date begin = y2010;
Date end = y2010m12d31;

Serie residuals = SubSer(Gaussian(0, 1, C), begin, end);

Polyn ar = 1 - 0.5*B; // - 0.2*B**2 +0.3*B**3;
Polyn ma = 1; // - 0.8*B;
Polyn dif = 1; // - B;

Serie noise0 = SubSer(Gaussian(0, 1, C), begin, end);
Serie noise = DifEq(ma/(ar*dif), 
  SubSer(residuals, Succ(begin, C, Degree(ar)), end), noise0);

Date date = y2010m03;
Real size = 1;
Set pulses = For(1, size, Serie(Real d) {
  Date dt = Succ(date, C, d-1);
  Pulse(dt,C)
});
Serie zero1 = 1-SetSum(pulses);
Serie missing1 = Log(zero1*Exp(1));

//////////////////////////////////////////////////////////////////////////////
// [1] Estimación de omitidos con las interrupciones de Estimate

Serie output1 = noise*missing1;

Set mod1 = ModelDef(output1, 1,0,1,0,
  Polyn dif, SetOfPolyn(ar), SetOfPolyn(ma),
  Copy(Empty), Copy(Empty));
Real Show(0, "ALL");
Set est1 = Estimate(mod1);
Real Show(1, "ALL");

Set results1 = BinGroup("<<", For(1, size, Set (Real d) {
  Date dt = Succ(date, C, d-1);
  Real omit = SerDat(est1[3][4], dt);
  Real resid = SerDat(est1[3][1], dt);
  [[ PutName("Omitido_"<<dt, omit), PutName("Residuo_"<<dt, resid) ]]
})) << For(Card(est1[4])-Card(Monomes(ar))-Card(Monomes(ma))+3, Card(est1[4]), Real (Real p) {
  Real arima = est1[4][p][4];
  Text name = est1[4][p][1]<<"_"<<est1[4][p][2]<<"_"<<est1[4][p][3];
  PutName(name, arima)
});

//////////////////////////////////////////////////////////////////////////////
// [2] Estimación de omitidos con pulsos

Serie output2 = noise*zero1;

Set mod2 = ModelDef(output2, 1,0,1,0,
  Polyn dif, SetOfPolyn(ar), SetOfPolyn(ma),
  EvalSet(pulses, Set(Serie s) { InputDef(1, -s) }), Copy(Empty));
Real Show(0, "ALL");
Set est2 = Estimate(mod2);
Real Show(1, "ALL");

Set results2 = BinGroup("<<", For(1, size, Set (Real d) {
  Date dt = Succ(date, C, d-1);
  Real omit = SerDat(est2[4][d][4], dt);
  Real resid = SerDat(est2[3][1], dt);
  [[ PutName("Omitido_"<<dt, omit), PutName("Residuo_"<<dt, resid) ]]
})) << For(Card(est2[4])-Card(Monomes(ar))-Card(Monomes(ma))+3, Card(est2[4]), Real (Real p) {
  Real arima = est2[4][p][4];
  Text name = est2[4][p][1]<<"_"<<est2[4][p][2]<<"_"<<est2[4][p][3];
  PutName(name, arima)
});

//////////////////////////////////////////////////////////////////////////////
// Resumen

Set [[ results1, results2 ]];

//////////////////////////////////////////////////////////////////////////////