Ticket #786: ejemplo2.tol

//////////////////////////////////////////////////////////////////////////////
// Definición

Real PutRandomSeed(2143);

Date begin = y2010;
Date end = y2010m12d31;

Serie noise = SubSer(Gaussian(0,0.1), begin, end);
Serie input1 = SubSer(Gaussian(0,1), Succ(begin,C,-2), end);
Serie input2 = SubSer(Gaussian(0,1), begin, end);
Serie output = noise + (0.2-0.1*B^2):input1 + 0.15*input2;

//////////////////////////////////////////////////////////////////////////////
// Estimación 1 (anteponiendo ceros a input2 para que no falle)

Set mod01 = @ModelDef(output, 1,0,1,0, 1, SetOfPolyn(1-0.1*B), SetOfPolyn(1), 
  [[ @InputDef(0.1+0.1*B^2, input1),
     @InputDef(0.1, CalInd(W,C)<<input2) ]], Copy(Empty) );

Real Show(0, "ALL");
Set est01 = Estimate(mod01);
Real Show(1, "ALL");

//////////////////////////////////////////////////////////////////////////////
// Estimación 2 (anteponiendo numeros muy altos a input 2 para que no falle)

Set mod02 = @ModelDef(output, 1,0,1,0, 1, SetOfPolyn(1-0.1*B), SetOfPolyn(1), 
  [[ @InputDef(0.1+0.1*B^2, input1),
     @InputDef(0.1, (10^10*CalInd(C,C))<<input2) ]], Copy(Empty) );

Real Show(0, "ALL");
Set est02 = Estimate(mod02);
Real Show(1, "ALL");

//////////////////////////////////////////////////////////////////////////////
// Estimación 3 (separando el input1 en dos para que no falle)

Set mod03 = @ModelDef(output, 1,0,1,0, 1, SetOfPolyn(1-0.1*B), SetOfPolyn(1), 
  [[ @InputDef(0.1, input1),
     @InputDef(0.1, (B^2):input1),
     @InputDef(0.1, input2) ]], Copy(Empty) );

Real Show(0, "ALL");
Set est03 = Estimate(mod03);
Real Show(1, "ALL");

//////////////////////////////////////////////////////////////////////////////
// Comparación

Set parametros = est01::ParameterInfo << est02::ParameterInfo
  << est03::ParameterInfo;

Set residuos = [[ est01::Series::Residuals, est02::Series::Residuals,
 est03::Series::Residuals ]];

//////////////////////////////////////////////////////////////////////////////