Ticket #1101: TestInstances.tol

//////////////////////////////////////////////////////////////////////////////
// Creación de los datos

Real no1 = Copy(NObject);

Set matrices = For(1, 500, Matrix (Real i) {
  Matrix return = Rand(50000, 1, 0, 1)
});

Real no2 = Copy(NObject);

Real no2 - no1; // 507
// RAM: + 288 MB

//////////////////////////////////////////////////////////////////////////////
// Funciones

NameBlock Instance1(Set object.) {
  // +9 NObject
  NameBlock a = [[
    Set data = DeepCopy(object.)
  ]];
  a
};

NameBlock Instance2(Set object.) {
  // Usando un artificio en la construción de la instancia
  // +6 NObject
  NameBlock a = [[
    Set data = Copy(Empty)
  ]];
  Set a::data := DeepCopy(object.);
  a
};

NameBlock Instance3(Set object.) {
  // +4 NObject
  NameBlock a = [[
    Set data = Copy(Empty)
  ]];
  Set a::data := DeepCopy(object.);
  //! Si se devuelve una copia no importa dónde se asignen los datos
  Copy(a)
};

//////////////////////////////////////////////////////////////////////////////
// Creación de las instancias

Real no3 = Copy(NObject);

Set matrices2 = EvalSet(matrices, Anything (Matrix m) {
  NameBlock _b = Instance1([[m]]);
  _b
  //Copy(_b)  esto reduce más aún
});

Real no4 = Copy(NObject);

Real no4 - no3; // 4505, 3005, 2005 (según sea Instance1, 2 o 3)
// RAM: + 288 MB

//////////////////////////////////////////////////////////////////////////////
// Destrucción de los datos originales

Real no5 = Copy(NObject);

Set matrices := Copy(Empty);

Real no6 = Copy(NObject);

Real no6 - no5; // 1, -499, -499 (según sea Instance1, 2 o 3)
// RAM:  -  0 MB (si es Instance1)
//       -288 MB (si es Instance2 o 3)

//////////////////////////////////////////////////////////////////////////////